Grosser Titel AN Excel übergeben

Hallo,

wenn du noch nach einer Lösung suchst:

habe ich hier ein Beispiel:
Der Titel hier in diesem Prog ist der Name einer Tabelle, die Mann auswählen kann.

REPORT Z_BP_GUI_DOWNLOAD.

PARAMETERs:
pa_dbtab(30) type c,
pa_sep(1) type c,
pa_head(1) type c,
pa_pfad type string.

START-OF-SELECTION.
perform downloadtable USING pa_dbtab pa_sep pa_head pa_pfad.

*-------------------------------------------------------

FORM downloadtable USING value(intable) type c
value(separator) type c
value(withheader) type c
value(datei_pfad) type string.

data: refintable TYPE REF TO data,
waouttable type string,
sbuffer type string,
itouttable like TABLE OF waouttable,
descintable type REF TO cl_abap_tabledescr,
descinstruc type REF TO cl_abap_structdescr.


FIELD-SYMBOLS:
<fsintable> TYPE ANY TABLE,
<fsinworkarea> TYPE ANY,
<fscompstruc> TYPE abap_compdescr,
<fsoutvalue> TYPE ANY.

try.
" §01 Interne Tabelle mit gleicher Struktur
" wie gewählte Datenbanktabelle anlegen,
" über ein Feldsymbol adressierbar machen und füllen
CREATE DATA refintable TYPE STANDARD TABLE OF (intable).

ASSIGN refintable->* to <fsintable>.

select * from (intable) into TABLE <fsintable>.

" §02 Beschreibung der internene Tabelle sowie
" deren Strukturkomponenten über RTTI holen
descintable ?= cl_abap_typedescr=>describe_by_data( <fsintable> ).

descinstruc ?= descintable->get_table_line_type( ).

" §03 Strukturkomponenten lesen und durch
" Trennzeichnen getrennt in Ausgabezeile sammeln
if not withheader is initial. "and datei_pfad is not initial.

concatenate 'TabellenName: ' intable into waouttable SEPARATED BY space.
* append waouttable.
WRITE: / waouttable.
APPEND waouttable to itouttable.
clear waouttable.
loop at descinstruc->components
ASSIGNING <fscompstruc>.
CONCATENATE waouttable <fscompstruc>-name separator into waouttable.
endloop.

WRITE: / waouttable.
APPEND waouttable to itouttable.
clear waouttable.
endif.

" §04 alle Datensaetze der Eingabetabelle abarbeiten
loop at <fsintable> ASSIGNING <fsinworkarea>.
" §05 alle Feldinhalte des Aktuellen
" Datensatzes sammeln
loop at descinstruc->components
ASSIGNING <fscompstruc>.

ASSIGN COMPONENT <fscompstruc>-name
of STRUCTURE <fsinworkarea> to <fsoutvalue>.

sbuffer = <fsoutvalue>.
CONDENSE sbuffer.

CONCATENATE waouttable sbuffer separator into waouttable.
endloop.

WRITE: / waouttable.
APPEND waouttable to itouttable.
clear waouttable.
endloop.

" §06 Tabelle auf den Präsentasionsserver laden
CALL METHOD CL_GUI_FRONTEND_SERVICES=>GUI_DOWNLOAD
EXPORTING
* BIN_FILESIZE =
FILENAME = datei_pfad
FILETYPE = 'ASC'
CHANGING
DATA_TAB = itouttable.

CATCH cx_sy_create_data_error.
WRITE: 'Datenbanktabelle nicht gefunden.'.

endtry.

ENDFORM. " downloadtable