E-Mail versand mit dem Anhang.

Code: Alles auswählen.

  ls_objpack-body_num   = tab_lines.
  ls_objpack-doc_type   = 'TXT'.            "====> 'RAW'
  ls_objpack-obj_name   = 'ANLAGE'.
  ls_objpack-obj_descr  = 'Report'.

Code: Alles auswählen.

report.

parameters: pi_recv type so_recname default 'user@abapforum.de'.
parameters: pi_head type so_text255 default 'email header'.
parameters: pi_objn type so_obj_nam default 'my email'.

data: ls_document_data  type          sodocchgi1,
      ls_receiver       type          somlreci1,
      lt_solisti1       type table of solisti1,
      lt_object_content type table of solisti1,
      lt_receiver       type table of somlreci1,
      lv_line_content   type          so_text255,
      lt_messages       type table of bapireturn-message,
      ls_message        type          bapireturn-message,
      lt_objpack        type table of sopcklsti1,
      ls_objpack        type          sopcklsti1,
      lt_objhead        type table of solisti1,
      ls_objhead        type          solisti1.

constants: lc_obj_langu   value 'D',
           lc_sensitivty  value 'O',
           lc_rec_type    value 'U',
           lc_com_type(3) value 'INT'.
"------------------------------------------------------------------
" test
"------------------------------------------------------------------
append sy-abcde to lt_messages.
append sy-abcde to lt_messages.
append sy-abcde to lt_messages.
append sy-abcde to lt_messages.
append sy-abcde to lt_messages.
append sy-abcde to lt_messages.
append sy-abcde to lt_messages.

"------------------------------------------------------------------
" anything to do ?
"------------------------------------------------------------------
if pi_recv is initial or lt_messages is initial.
  return.
endif.

"------------------------------------------------------------------
" set document attributes
"------------------------------------------------------------------
ls_document_data-obj_name   = pi_objn.       "  'Test mail'
ls_document_data-obj_descr  = pi_head.   "      'E-Mail mit Anhang'
ls_document_data-obj_langu  = lc_obj_langu.     "VALUE 'D'.
ls_document_data-sensitivty = lc_sensitivty.    "VALUE 'O'.

"------------------------------------------------------------------
" set receiver of the message
"------------------------------------------------------------------
clear lt_receiver.
ls_receiver-receiver  = pi_recv.
ls_receiver-rec_type  = lc_rec_type.            "VALUE 'U'.
ls_receiver-com_type  = lc_com_type.            "VALUE 'INT'.
append ls_receiver   to lt_receiver.

"------------------------------------------------------------------
"mail body
"------------------------------------------------------------------

"mail body content
refresh lt_solisti1.
append 'Sehr geehrte damen und herren' to lt_solisti1.
append space                           to lt_solisti1.
append 'anbei übersenden wir ihnen   ' to lt_solisti1.
append 'mit freundlichen Grüssen     ' to lt_solisti1.

* mail body packlist
clear ls_objpack.
clear ls_objpack-transf_bin.
ls_objpack-head_start =  0.
ls_objpack-head_num   =  0.
ls_objpack-body_start =  lines( lt_object_content ) + 1.
ls_objpack-body_num   =  lines( lt_solisti1 ).
ls_objpack-doc_type   =  'RAW'.
append ls_objpack     to lt_objpack.

append lines of lt_solisti1 to lt_object_content.

"------------------------------------------------------------------
"attachment
"------------------------------------------------------------------

"attachment content
refresh lt_solisti1.
lv_line_content       = pi_head.
clear lv_line_content.
append lv_line_content to lt_solisti1.

loop at lt_messages into ls_message.
  lv_line_content = ls_message.
  append lv_line_content to lt_solisti1.
*    add empty line
  clear: lv_line_content.
  append lv_line_content to lt_solisti1.
endloop.

append ls_document_data-obj_name to lt_solisti1.

"attachment header
ls_objhead = 'Report.TXT'.
append ls_objhead  to lt_objhead .

"attachment packlist
clear ls_objpack.
clear ls_objpack-transf_bin.
ls_objpack-head_start = 1.
ls_objpack-head_num   = 1.
ls_objpack-body_start = lines( lt_object_content ) + 1.
ls_objpack-body_num   = lines( lt_solisti1 ).
ls_objpack-doc_type   = 'RAW'.
ls_objpack-obj_name   = 'ANLAGE'.
ls_objpack-obj_descr  = 'Report'.
ls_objpack-doc_size   = lines( lt_solisti1 ) * 255.
append ls_objpack to lt_objpack.

append lines of lt_solisti1 to lt_object_content.

"------------------------------------------------------------------
"send email
"------------------------------------------------------------------
call function 'SO_NEW_DOCUMENT_ATT_SEND_API1'
  exporting
    document_data              = ls_document_data
    put_in_outbox              = 'X'
    commit_work                = 'X'
  tables
    packing_list               = lt_objpack
    object_header              = lt_objhead
*   contents_bin               = lt_objbin
    contents_txt               = lt_object_content
    receivers                  = lt_receiver
  exceptions
    too_many_receivers         = 1
    document_not_sent          = 2
    document_type_not_exist    = 3
    operation_no_authorization = 4
    parameter_error            = 5
    x_error                    = 6
    enqueue_error              = 7
    others                     = 8.

if sy-subrc ne 0.
   "..................
   "..................
   "..................
   "..................
endif.