Tabelle editieren

Code: Alles auswählen.

 MODIFY zworkflow FROM TABLE i_modified.

Code: Alles auswählen.

*&---------------------------------------------------------------------*
*& Report  YUSERMENU                                                   *
*&                                                                     *
*&---------------------------------------------------------------------*
*&                                                                     *
*&                                                                     *
*&---------------------------------------------------------------------*

REPORT  YUSERMENU                                                   .
* Tabellen der Varianten
* ltdx
* Ltdxd
* Ltdxs

TABLES: yuserprog,trdirt.

INCLUDE <icon>.


DATA it_data TYPE TABLE OF yuserprog WITH HEADER LINE.

DATA lv_layperm(1) VALUE space.

DATA dyname TYPE  d020s-prog VALUE sy-repid.
DATA dynumb TYPE  d020s-dnum VALUE '0100'.

* Grid Parameter
DATA: ok_code LIKE sy-ucomm,
      g_container TYPE scrfname VALUE 'BCALV_CONTAINER',
      grid1  TYPE REF TO cl_gui_alv_grid,
      g_custom_container TYPE REF TO cl_gui_custom_container,
      is_variant TYPE disvariant.

*--- Field catalog table
DATA gt_fieldcat TYPE lvc_t_fcat WITH HEADER LINE.
*--- Layout structure
DATA gs_layout TYPE lvc_s_layo .

* LT_EXCLUDE => Tabelle zum Ausschliessen von Funktionen innerhalb
* der Toolbar des ALV-Grid
DATA: lt_exclude TYPE ui_functions,
      ls_exclude TYPE ui_func.
*---------------------------------------------------------------------*
*       MAIN                                                          *
*---------------------------------------------------------------------*
INITIALIZATION.
*---------------------------------------------------------------------*
*       CLASS lcl_event_handler DEFINITION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_event_handler DEFINITION .
  PUBLIC SECTION .
    METHODS:
*--To add new functional buttons to the ALV toolbar
    handle_toolbar FOR EVENT toolbar OF cl_gui_alv_grid
    IMPORTING e_object e_interactive ,

*--To implement user commands
    handle_user_command
    FOR EVENT user_command OF cl_gui_alv_grid
    IMPORTING e_ucomm .



*--To be triggered before user commands
*handle_before_user_command
*FOR EVENT before_user_command OF cl_gui_alv_grid
*IMPORTING e_ucomm.

*--Double-click control
*handle_double_click
*FOR EVENT double_click OF cl_gui_alv_grid
*IMPORTING e_row e_column es_row_no.

  PRIVATE SECTION.
ENDCLASS.                    "lcl_event_handler DEFINITION


*---------------------------------------------------------------------*
*       CLASS lcl_event_handler IMPLEMENTATION
*---------------------------------------------------------------------*
*
*---------------------------------------------------------------------*
CLASS lcl_event_handler IMPLEMENTATION .

*--Handle Toolbar
  METHOD handle_toolbar.
    PERFORM handle_toolbar USING e_object e_interactive .
  ENDMETHOD .                    "handle_toolbar

*--Handle User Command
  METHOD handle_user_command .
    PERFORM handle_user_command USING e_ucomm .
  ENDMETHOD.                    "handle_user_command

*--Handle Before User Command JG
*  METHOD handle_before_user_command .
*    PERFORM handle_before_user_command USING e_ucomm .
*  ENDMETHOD .                    "handle_before_user_command


ENDCLASS.                    "lcl_event_handler IMPLEMENTATION

DATA gr_event_handler TYPE REF TO lcl_event_handler .
* Eingabe und Auswertung ---------------------------------------------*

START-OF-SELECTION.

  SELECT * FROM yuserprog APPENDING TABLE it_data
  WHERE benutzer = sy-uname.




  CALL SCREEN 100.

  EXIT.
*&---------------------------------------------------------------------*
*&      Module  PBO  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE pbo OUTPUT.
  IF g_custom_container IS INITIAL.
    CREATE OBJECT g_custom_container
           EXPORTING container_name = g_container.
    CREATE OBJECT grid1
           EXPORTING i_parent = g_custom_container.

*--Creating an instance for the event handler
    CREATE OBJECT gr_event_handler .

*----Preparing field catalog.
    PERFORM prepare_field_catalog TABLES gt_fieldcat[] .
*----Preparing layout structure
    PERFORM prepare_layout CHANGING gs_layout .
*----Preparing Disable Toolbar Buttons
    PERFORM change_buttons .

    is_variant-report = dyname.

*'X': global saving only
*'U': user-specific saving only
*'A': corresponds to 'X' and 'U'
*SPACE: no saving


* Prüfe auf Berechtigung BENUTZERPFLEGE SU01
* dann ist Layout-Anpassung erlaubt
    CALL FUNCTION 'AUTHORITY_CHECK_TCODE'
      EXPORTING
        tcode  = 'SU01'
      EXCEPTIONS
        ok     = 1
        not_ok = 2
        OTHERS = 3.

    IF sy-subrc = 1.
      lv_layperm = 'A'.
    ENDIF.



    CALL METHOD grid1->set_table_for_first_display
      EXPORTING
        is_variant           = is_variant
        i_save               = lv_layperm
*        i_save               = ' '
        is_layout            = gs_layout
        it_toolbar_excluding = lt_exclude
      CHANGING
        it_outtab            = it_data[]
        it_fieldcatalog      = gt_fieldcat[].


*--Registering handler methods to handle ALV Grid events JG

    SET HANDLER gr_event_handler->handle_toolbar FOR grid1.
    SET HANDLER gr_event_handler->handle_user_command FOR grid1.

* Die Toolbar des Grids muss noch auf interactive
* geschaltet werden. Dadurch werden die
* definierten Buttons angezeigt und die
* oben im PERFORM change_buttons ausgeschalteten
* Buttons heraus genommen werden

    CALL METHOD grid1->set_toolbar_interactive.


    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.


* Der GRID1 wird noch refreshed
    CALL METHOD grid1->refresh_table_display.


  ENDIF.

  SET PF-STATUS 'MAIN100'.
  SET TITLEBAR 'AUSW' WITH text-001.

ENDMODULE.                 " PBO  OUTPUT
*&---------------------------------------------------------------------*
*&      Module  PAI  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE pai INPUT.
*   to react on oi_custom_events:
  CALL METHOD cl_gui_cfw=>dispatch.
  CASE ok_code.
    WHEN 'EXIT'.
      LEAVE TO SCREEN 0.
    WHEN OTHERS.
*     do nothing
  ENDCASE.
  CLEAR ok_code.

ENDMODULE.                 " PAI  INPUT
*&--------------------------------------------------------------------*
*&      Form  prepare_field_catalog
*&--------------------------------------------------------------------*
*       text
*---------------------------------------------------------------------*
*      -->PT_FIELDCATtext
*---------------------------------------------------------------------*
FORM prepare_field_catalog TABLES pt_fieldcat TYPE lvc_t_fcat .

  DATA ls_fcat TYPE lvc_s_fcat .
*  DATA lv_depth TYPE i.

  CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
      i_structure_name       = 'YUSERPROG'
    CHANGING
      ct_fieldcat            = pt_fieldcat[]
    EXCEPTIONS
      inconsistent_interface = 1
      program_error          = 2
      OTHERS                 = 3.

*  DELETE pt_fieldcat WHERE
*  fieldname EQ 'BENUTZER'.


  LOOP AT pt_fieldcat INTO ls_fcat .

    ls_fcat-col_pos = sy-tabix.

    CASE ls_fcat-fieldname.
      WHEN 'PROGNAME' .
        ls_fcat-coltext = 'Name des Reports'.
        ls_fcat-key = space.
        ls_fcat-emphasize = space.

      WHEN 'TEXT' .
        ls_fcat-coltext = 'Beschreibung'.
    ENDCASE.

    MODIFY pt_fieldcat FROM ls_fcat .

  ENDLOOP.

ENDFORM .                    "prepare_field_catalog
*&--------------------------------------------------------------------*
*&      Form  prepare_layout
*&--------------------------------------------------------------------*
*       text
*---------------------------------------------------------------------*
*      -->PS_LAYOUT  text
*---------------------------------------------------------------------*
FORM prepare_layout CHANGING ps_layout TYPE lvc_s_layo.
  ps_layout-zebra = 'X' .
  ps_layout-cwidth_opt ='X'.
  ps_layout-numc_total = ' '.
  ps_layout-no_merging = 'X'.
  ps_layout-no_rowmark = ' '.
  ps_layout-sel_mode = 'A'.
  ps_layout-no_toolbar = ' '.

*  ps_layout-grid_title = 'Flights' .
*  ps_layout-smalltitle = 'X' .
ENDFORM.                    "prepare_layout

*&--------------------------------------------------------------------*
*&      Form  handle_toolbar
*&--------------------------------------------------------------------*
*       text
*---------------------------------------------------------------------*
*      -->I_OBJECT   text
*---------------------------------------------------------------------*
FORM handle_toolbar USING i_object TYPE REF TO cl_alv_event_toolbar_set
e_interactive .

  DATA: ls_toolbar TYPE stb_button.

* Paltzhalter / Seperator
  CLEAR ls_toolbar.
  MOVE 3 TO ls_toolbar-butn_type.
  APPEND ls_toolbar TO i_object->mt_toolbar.

* Button MARKIEREN
  CLEAR ls_toolbar.
  MOVE 'MARK' TO ls_toolbar-function.                       "#EC NOTEXT
  MOVE icon_execute_object TO ls_toolbar-icon.
  MOVE 'Programm ausführen'(201) TO ls_toolbar-quickinfo.
  MOVE ' Programm ausführen'(201) TO ls_toolbar-text.
  MOVE ' ' TO ls_toolbar-disabled.                          "#EC NOTEXT
  APPEND ls_toolbar TO i_object->mt_toolbar.

ENDFORM .                    "handle_toolbar

*&--------------------------------------------------------------------*
*&      Form  Change_buttons
*&--------------------------------------------------------------------*
*       text
*---------------------------------------------------------------------*
FORM change_buttons .
* Kein Symbol für Drucken / Graphik / Info
  ls_exclude = cl_gui_alv_grid=>mc_fc_print_back.
  APPEND ls_exclude TO lt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_graph.
  APPEND ls_exclude TO lt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_info.
  APPEND ls_exclude TO lt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_mb_subtot.
  APPEND ls_exclude TO lt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_mb_sum.
  APPEND ls_exclude TO lt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_mb_view.
  APPEND ls_exclude TO lt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_detail.
  APPEND ls_exclude TO lt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_find.
  APPEND ls_exclude TO lt_exclude.

ENDFORM.                    "Change_buttons

*&--------------------------------------------------------------------*
*&      Form  handle_user_command
*&--------------------------------------------------------------------*
*       text
*---------------------------------------------------------------------*
*      -->I_UCOMM    text
*---------------------------------------------------------------------*
FORM handle_user_command USING i_ucomm TYPE syucomm .
  DATA lt_selected_rows TYPE lvc_t_roid .
  DATA ls_selected_row TYPE lvc_s_roid .


  CASE i_ucomm .
    WHEN 'MARK' .

      CALL METHOD grid1->get_selected_rows
        IMPORTING
          et_row_no = lt_selected_rows.
*     War was selektiert ?
      READ TABLE lt_selected_rows INTO ls_selected_row INDEX 1 .

      IF sy-subrc NE 0 .
        MESSAGE s000(su) WITH 'Bitte eine Zeile selektieren !'(205).
      ELSE.
        LOOP AT lt_selected_rows INTO ls_selected_row.
          IF ls_selected_row-row_id NE 0.
            READ TABLE it_data INDEX ls_selected_row-row_id.
            PERFORM run_report USING it_data-programm.
            EXIT.
          ENDIF.
        ENDLOOP.

* Falls die Tabelle yuserprog von hier aus gepflegt wird (Sonderfall)
        REFRESH it_data.
        SELECT * FROM yuserprog APPENDING TABLE it_data
        WHERE benutzer = sy-uname.

        CALL METHOD grid1->refresh_table_display
*       EXPORTING
*       IS_STABLE =
*       I_SOFT_REFRESH =
        EXCEPTIONS
        finished = 1
        OTHERS = 2 .

      ENDIF .


  ENDCASE .
ENDFORM.                    "handle_user_command

*&--------------------------------------------------------------------*
*&      Form  Run_report
*&--------------------------------------------------------------------*
*       Starten eines Reports typ 1 via CALL TRANSCTION
*---------------------------------------------------------------------*
FORM run_report USING repo TYPE rs38m-programm.

  DATA: bdcdata TYPE TABLE OF bdcdata.
  DATA: itab TYPE TABLE OF bdcmsgcoll.
  DATA: program LIKE sy-repid,
        wa_bdcdata TYPE bdcdata.


  CLEAR wa_bdcdata.
  wa_bdcdata-program  = 'SAPMS38M'.
  wa_bdcdata-dynpro   = '0101'.
  wa_bdcdata-dynbegin = 'X'.
  APPEND wa_bdcdata TO bdcdata.

  CLEAR wa_bdcdata.
  wa_bdcdata-fnam     = 'BDC_CURSOR'.
  wa_bdcdata-fval     = 'RS38M-PROGRAMM'.
  APPEND wa_bdcdata TO bdcdata.

  CLEAR wa_bdcdata.
  wa_bdcdata-fnam     = 'BDC_OKCODE'.
  wa_bdcdata-fval     = '=STRT'.
  APPEND wa_bdcdata TO bdcdata.

  CLEAR wa_bdcdata.
  wa_bdcdata-fnam     = 'RS38M-PROGRAMM'.
  wa_bdcdata-fval     = repo.
  APPEND wa_bdcdata TO bdcdata.

  CALL TRANSACTION 'SA38'  USING bdcdata  MODE 'E'
                           MESSAGES INTO itab.

ENDFORM.                    "Run_report