ALV (Grid): Seitenumbruch bei Feldänderung

Code: Alles auswählen.

REPORT  ztestalv.

DATA: gt_alv TYPE TABLE OF sflight,
*     Tabelle für den Feldkatalog des ALV
      gt_fieldcat      TYPE lvc_t_fcat,
*     Tabelle/Arbeitsbreich für die Sortierung des ALV
      gt_sort              TYPE lvc_t_sort,
      gs_sort              TYPE lvc_s_sort,
*     Arbeitsbreich für die Druckoptionen des ALV
      gs_print             TYPE lvc_s_prnt.

FIELD-SYMBOLS <fs_fieldcat> TYPE lvc_s_fcat.
**********************************************************************
PARAMETERS: p_count TYPE i.
**********************************************************************
START-OF-SELECTION.

  SELECT *
    FROM sflight
    INTO TABLE gt_alv
    UP TO p_count ROWS.

* Fieldcat
  CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
      i_structure_name       = 'SFLIGHT'
    CHANGING
      ct_fieldcat            = gt_fieldcat
    EXCEPTIONS
      inconsistent_interface = 1
      program_error          = 2
      OTHERS                 = 3.

  IF sy-subrc <> 0.
    MESSAGE 'Generierung des Feldkatalogs schlug fehl.' TYPE 'E'.
  ENDIF.

  LOOP AT gt_fieldcat ASSIGNING <fs_fieldcat> WHERE fieldname = 'CARRID'.
    <fs_fieldcat>-no_out = 'X'.       "soll nicht ausgegeben werden
  ENDLOOP.

* Sortierung
  CLEAR: gs_sort, gt_sort.
  gs_sort-spos      = 1.
  gs_sort-fieldname = 'CARRID'.
  gs_sort-up        = 'X'.
*Beim Drucken eine neue Seite je Gruppenstufenwechsel
  gs_sort-group     = '*'.  
* oder beim Drucken ein Unterstrich bei Gruppenstufenwechsel
*gs_sort-group = 'UL'.  
 APPEND gs_sort TO gt_sort. CLEAR gs_sort.

* Printoptions
  gs_print-grpchgedit = 'X'.  "Auf Gruppenstufen reagieren

  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
    EXPORTING
      it_fieldcat_lvc = gt_fieldcat
      it_sort_lvc     = gt_sort
      is_print_lvc    = gs_print
    TABLES
      t_outtab        = gt_alv
    EXCEPTIONS
      program_error   = 1
      OTHERS          = 2.
  IF sy-subrc <> 0.
    MESSAGE 'Fehler bei der ALV-Ausgabe' TYPE 'E'.
  ENDIF.