ALV Feldkatalog automatisch generieren

Code: Alles auswählen.

data: lt_table type foo.
data: lt_fcat type lvc_t_fcat.

data: lo_columns      type ref to cl_salv_columns_table,
      lo_aggregations type ref to cl_salv_aggregations,
      lo_salv_table   type ref to cl_salv_table,
      lr_table        type ref to data.

field-symbols: <table> type standard table.

create data lr_table like lt_table.
assign lr_table->* to <table>.

try.
    cl_salv_table=>factory(
      exporting
        list_display = abap_false
      importing
        r_salv_table = lo_salv_table
      changing
        t_table      = <table> ).
  catch cx_salv_msg.
endtry.

* get columns object (raw fieldcatalog)
lo_columns  = lo_salv_table->get_columns( ).

* get aggregationss object (sorts)
lo_aggregations = lo_salv_table->get_aggregations( ).
lt_fcat =
  cl_salv_controller_metadata=>get_lvc_fieldcatalog(
    r_columns             = lo_columns
    r_aggregations        = lo_aggregations ).

Code: Alles auswählen.

FORM create_fieldcat USING    ls_structure
                     CHANGING ls_fieldcat  TYPE lvc_s_fcat
                              lt_fieldcat  TYPE lvc_t_fcat.

* Deklarieren der Referenz ref_Structdescr
* sowie die Tabelle(lt_fields) die später die Feldbeschreibungen
* enthält.
  DATA: ref_structdescr TYPE REF TO cl_abap_structdescr,
        lt_fields       TYPE        ddfields.

* Deklaration eines Zählers um die Spaltenposition festzulegen.
  DATA: lv_col_i TYPE i VALUE 0.
* Feld Symbol für Loop...Assigning am Ende der Routine.
  FIELD-SYMBOLS: <fs_fields> TYPE LINE OF ddfields.

* Setzen der Referenz der Strukturbeschreibung anhand eines Downcasts
* des Rückgabewerts der methode describe_by_data der klasse
* cl_abap_structdescr der den Parameter p_data nutzt welcher
* die zu verwertende Struktur enthält.
  ref_structdescr ?= cl_abap_structdescr=>describe_by_data(
                                          p_data = ls_structure
                                          ).

* Die Methode der read_structdescr der Klasse cl_salv_data_descr
* um das Objekt auszuwerten und in eine Tabelle zu übertragen.
  CALL METHOD cl_salv_data_descr=>read_structdescr
    EXPORTING
      r_structdescr = ref_structdescr
    RECEIVING
      t_dfies       = lt_fields.

* Loop über die Feldbeschreibung um alle Daten in den Feldkatalog zu
* übertragen und evtl. mithilfe von If-Bedingungen sonderfälle zu
* steuern
  LOOP AT lt_fields ASSIGNING <fs_fields>.

*   Struktur leeren um Fehler zu vermeiden.
    CLEAR ls_fieldcat.

*   Zähler um 1 erhöhen um die Sortierung der Spalten zu ermöglichen
    ADD 1 TO lv_col_i.

*   Übertragen diverser Daten aus Strukturbeschreibung in Feldkatalog.
    ls_fieldcat-col_pos    = lv_col_i.               "spaltenposition
    ls_fieldcat-fieldname  = <fs_fields>-fieldname.  "Feldname
    ls_fieldcat-tabname    = <fs_fields>-tabname.    "LVC-Tabname ?
    ls_fieldcat-scrtext_l  = <fs_fields>-scrtext_l.  "feldbezeichner L
    ls_fieldcat-scrtext_m  = <fs_fields>-scrtext_m.  "feldbezeichner M
    ls_fieldcat-scrtext_s  = <fs_fields>-scrtext_s.  "feldbezeichner s
    ls_fieldcat-ref_field  = <fs_fields>-reffield.   "referenzfeld
    ls_fieldcat-ref_table  = <fs_fields>-reftable.   "referenztabelle
    ls_fieldcat-intlen     = <fs_fields>-intlen.     "interne länge
    ls_fieldcat-inttype    = <fs_fields>-inttype.    "interner datentyp
    ls_fieldcat-lowercase  = <fs_fields>-lowercase.  "kleinschreiben j/n
    ls_fieldcat-outputlen  = <fs_fields>-outputlen. "ausgabelänge
    ls_fieldcat-decimals_o = <fs_fields>-decimals. "ausgabedezimalstelln
    ls_fieldcat-convexit   = <fs_fields>-convexit. "konvertierunlsroutin
    ls_fieldcat-decimals   = <fs_fields>-decimals. "anzahl dezimalstelle
    ls_fieldcat-reptext    = <fs_fields>-reptext.  "
    ls_fieldcat-rollname   = <fs_fields>-rollname. "Datenelement für F1
    ls_fieldcat-domname    = <fs_fields>-domname.   "Name der Domäne
    ls_fieldcat-datatype   = <fs_fields>-datatype.  "DictionaryDatentyp
    ls_fieldcat-mac        = <fs_fields>-mac.      "suchhilfe j/n
    ls_fieldcat-f4availabl = <fs_fields>-f4availabl. "F4 hilfe j/n
    ls_fieldcat-checktable = <fs_fields>-checktable. "?????
    ls_fieldcat-col_opt    = abap_false.       "Spaltenoptimierung *X/''.,
    
    append ls_fieldcat to lt_fieldcat.
  ENDLOOP.

Code: Alles auswählen.

do.
  assign component sy-index of structure ls_structure to <la_field>.
  if sy-subrc ne 0.
    exit.
  endif.
  describe field <la_field> type ld_type length ld_length.
enddo.