Auslesen eines Exportparameters generischen Typs

Code: Alles auswählen.

CLASS class_dyn_export_param DEFINITION.
  PUBLIC SECTION.

    " Select-from hat einen dynamisch typisierten Parameter
    CLASS-METHODS select_from
       IMPORTING
          table_name TYPE tabname
       EXPORTING
           content TYPE ANY TABLE.

    " Hülle für Methode select_from, die die passende Datenreferenz
    " übergibt
    CLASS-METHODS select_from_wrapper
       IMPORTING
          table_name TYPE tabname
       EXPORTING
           content TYPE REF TO DATA.

ENDCLASS.

CLASS class_dyn_export_param IMPLEMENTATION.

  METHOD select_from.
     SELECT * FROM (table_name) INTO TABLE content.
  ENDMETHOD.

  METHOD select_from_wrapper.
     FIELD-SYMBOLS: <content> TYPE ANY TABLE.

     " Erzeugen der Datenreferenz mit dem passenden Datentyp
     CREATE DATA content TYPE STANDARD TABLE OF (table_name).

     ASSIGN content->* TO <content>.
     select_from( EXPORTING table_name = table_name
       IMPORTING content = <content> ).

  ENDMETHOD.

ENDCLASS.

Code: Alles auswählen.

START-OF-SELECTION.
  FIELD-SYMBOLS: <content> TYPE ANY TABLE.

  class_dyn_export_param=>select_from_wrapper( EXPORTING table_name = 'SCARR'
    IMPORTING content = DATA(content) ).
  ASSIGN content->* TO <content>.
  cl_demo_output=>display( <content> ).