LOB-Feld komprimiert ablegen oder DB erledigen lassen?

Code: Alles auswählen.

REPORT LINE-SIZE 1000.

CLASS lcl_check_zip_db DEFINITION FINAL.
  PUBLIC SECTION.
    METHODS:
      main IMPORTING iv_iterations TYPE i,
      create_data IMPORTING iv_lines       TYPE i
                  RETURNING VALUE(rv_data) TYPE string,
      save_data IMPORTING iv_zip                    TYPE abap_bool
                          iv_data_to_save           TYPE string
                RETURNING VALUE(rv_compressed_size) TYPE i.
ENDCLASS.

PARAMETERS: iterate TYPE i OBLIGATORY DEFAULT 4.

END-OF-SELECTION.
  NEW lcl_check_zip_db( )->main( iterate ).

CLASS lcl_check_zip_db IMPLEMENTATION.
  METHOD main.
    DATA: lv_lines                    TYPE i VALUE 1,
          lv_data                     TYPE string,
          lv_start                    TYPE i,
          lv_end                      TYPE i,
          lv_runtime_no_compression   TYPE i,
          lv_runtime_with_compression TYPE i,
          lv_compressed_size          TYPE i,
          lv_diff                     TYPE i,
          lv_ratio                    TYPE f.


    FORMAT COLOR 5 INTENSIFIED OFF.
    WRITE:/ 'DB-Type:', sy-dbsys INTENSIFIED ON.
    FORMAT COLOR OFF INTENSIFIED ON.

    DO iterate TIMES.
* Cleanup DB before each write statement.
      DELETE FROM zss_test1 WHERE compressed <> 'Z'. "
      COMMIT WORK.
      lv_lines = lv_lines * 2.
      WRITE:/ 'Lines:', lv_lines COLOR 3.
      lv_data = me->create_data( lv_lines ).
      WRITE: AT 20 'Datasize:', strlen( lv_data ) COLOR 3.
* Ohne Komprimierung
      GET RUN TIME FIELD lv_start.
      me->save_data( iv_zip = abap_false iv_data_to_save = lv_data ).
      GET RUN TIME FIELD lv_end.
      lv_runtime_no_compression = lv_end - lv_start.
      WRITE: AT 45 'Runtime no compression in ABAP:', lv_runtime_no_compression COLOR 3.
* Mit Komprimierung
* Cleanup DB before each write statement.
      DELETE FROM zss_test1 WHERE compressed <> 'Z'. "
      COMMIT WORK.
      GET RUN TIME FIELD lv_start.
      lv_compressed_size = me->save_data( iv_zip = abap_true iv_data_to_save = lv_data ).
      GET RUN TIME FIELD lv_end.
      lv_runtime_with_compression = lv_end - lv_start.
      WRITE: AT 90 'Runtime with compression in ABAP:', lv_runtime_with_compression COLOR 3,
             AT 140 'With compressed size', lv_compressed_size COLOR 3.
      lv_diff = lv_runtime_with_compression - lv_runtime_no_compression.
      WRITE: AT 175 'Difference', lv_diff COLOR 7.
      lv_ratio = lv_runtime_with_compression / lv_runtime_no_compression.
      WRITE: AT 200 'Ratio', lv_ratio COLOR 7 EXPONENT 0 DECIMALS 2.

    ENDDO.
  ENDMETHOD.

  METHOD save_data.
    DATA: ls_data TYPE zss_test1,  " ZSS_TEST1 also name of database
          lv_x    TYPE xstring.
    IF iv_zip = abap_false.
      ls_data = VALUE #( compressed = ''
                         data_s     = iv_data_to_save
                       ).
      MODIFY zss_test1 FROM @ls_data.
      COMMIT WORK.
    ELSE.
* Zip first
      TRY.
          cl_abap_gzip=>compress_text( EXPORTING
                                         text_in                    = iv_data_to_save      " Input Text
                                      IMPORTING
                                        gzip_out                   = lv_x                  " Compressed output
                                        gzip_out_len               = rv_compressed_size    " Output Length
                                    ).
        CATCH cx_root.
          ASSERT 1 = 2.
      ENDTRY.
      ls_data = VALUE #( compressed = 'X'
                         data_x     = lv_x
                       ).
      MODIFY zss_test1 FROM @ls_data.
      COMMIT WORK.
    ENDIF.
  ENDMETHOD.

  METHOD create_data.
    SELECT *
      FROM dd03l
    INTO TABLE @DATA(lt_dd03l) UP TO  @iv_lines ROWS.
    WHILE lines( lt_dd03l ) < iv_lines.
      APPEND LINES OF lt_dd03l TO lt_dd03l.
    ENDWHILE.
    DELETE lt_dd03l FROM iv_lines + 1.

    CALL TRANSFORMATION id
      SOURCE data = lt_dd03l
      RESULT XML rv_data.
  ENDMETHOD.
ENDCLASS.