Mit Count nach ganzem Alphabet suchen?

Code: Alles auswählen.

PARAMETERS word TYPE string DEFAULT 'AAALAAF'.


INTERFACE if_count.
  TYPES: BEGIN OF ts_result,
           char TYPE c LENGTH 1,
           occ  TYPE i,
         END OF ts_result,
         tt_result TYPE SORTED TABLE OF ts_result WITH UNIQUE KEY char.
  METHODS count
    IMPORTING
      word          TYPE string
    RETURNING
      VALUE(result) TYPE tt_result.
ENDINTERFACE.

CLASS sol_reduce DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_count.
ENDCLASS.

CLASS sol_reduce IMPLEMENTATION.
  METHOD if_count~count.
    result = REDUCE if_count=>tt_result(
      INIT res = VALUE #( )
        FOR i = 0 THEN i + 1 WHILE i < strlen( word )
          NEXT res = COND #( WHEN NOT line_exists( res[ char = word+i(1) ] ) THEN
            VALUE #( BASE res (
              char = word+i(1)
              occ  = count_any_of( val = word sub = word+i(1)  ) ) ) ELSE res )  ).

  ENDMETHOD.
ENDCLASS.


CLASS sol_while DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_count.
ENDCLASS.

CLASS sol_while IMPLEMENTATION.
  METHOD if_count~count.

    DATA j TYPE i.

    WHILE j < strlen( word ).
      DATA(current) = word+j(1).
      ADD 1 TO j.
      IF NOT line_exists( result[ char = current ] ).
        INSERT VALUE #( char = current occ = count_any_of( val = word sub = current ) ) INTO TABLE result.
      ENDIF.
    ENDWHILE.

  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.

  DATA(out) = cl_demo_output=>new( ).
  out->write_data( CAST if_count( NEW sol_reduce( ) )->count( word ) ).
  out->write_data( CAST if_count( NEW sol_while( ) )->count( word ) ).

  out->display( ).