How-To: Materialstamm Feldanpassung Dynprosteuerung

Posten Sie hier Tutorials & Cookbooks.
10 Beiträge • Seite 1 von 1
10 Beiträge Seite 1 von 1

How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von Tron (Top Expert / 1327 / 35 / 331 ) »
Feldanpassung im Materialstamm

Beispiel: Eingabebereitschaft des Feldes MARA-MSTAE unterbinden

Bitte unbedingt im Einführungsleitfaden (SPRO) den Punkt:
So wird's gemacht (Quick-Guide anhand eines Beispiels) durchlesen !

Das markierte Feld soll nicht mehr Eingabebereit sein.
Bild
Nachdem Du eine Funktionsgruppe angelegt hast und via Customizing die
Funktionsgruppe kopiert wurde,
kopierst Du nun:
Bild
in Deine neue Funktionsgruppe und aktivierst das Dynpro (erstmal).
Bild

Jetzt musst Du die Bildsequenz anpassen.(aber bitte die RICHTIGE !)
Bild
Bild

und trägst das kopierte Programm(die Funktionsgruppe) plus Dynpro ein.

Bild
(Der "Ergonomische" Aufbau dieses Pflegeviews ist doch immer wieder ein Genuß)

wenn alles richtig läuft (kleiner Scherz):
Bild

Nun noch PBO des neuen Dynpros (e.g.8001) anpassen:
Zurück zu Deinem kopierten Dynpro.
Jetzt fügst Du ein Modul (e.g.module user_spec) ein.

Code: Alles auswählen.

PROCESS BEFORE OUTPUT.
*                      Verarbeitung vor der Ausgabe

  MODULE INIT_SUB.
  MODULE GET_DATEN_SUB.
  MODULE FELDAUSWAHL.
  MODULE SONDERFAUS.
  MODULE SONFAUSW_IN_FGRUPPEN.
  MODULE FAUSW_BEZEICHNUNGEN.
  MODULE BILDSTATUS.
  MODULE FELDHISTORIE.                         "Aenderungsdienst
  MODULE ZUSREF_VORSCHLAGEN_B.
  MODULE REFDATEN_VORSCHLAGEN.
  MODULE ZUSREF_VORSCHLAGEN_A.
  MODULE BEZEICHNUNGEN_LESEN.
*********************************************
* ÄNDERUNG Customer Screen modification ÄNDERUNG
  module user_spec.
*********************************************
  MODULE SET_DATEN_SUB.


PROCESS AFTER INPUT.
*                      Verarbeitung nach der Eingabe

  MODULE GET_DATEN_SUB.
  FIELD: MARA-KOSCH.       "mk/3.1H fehlte

  CHAIN.
     FIELD MARA-MEINS.
           MODULE MARA-MEINS.
  ENDCHAIN.

* AHE: 07.04.99 - A (4.6a) HW 181769
  CHAIN.
     FIELD MARA-EXTWG.
           MODULE MARA-EXTWG.
  ENDCHAIN.
* AHE: 07.04.99 - E

  CHAIN.
     FIELD MARA-MATKL.
*          MODULE MARA-MATKL ON CHAIN-REQUEST. "nicht benutzen wg Vorsch
                                               "/cf/11.5.95/
           MODULE MARA-MATKL.
  ENDCHAIN.
  FIELD MARA-BISMT.
  FIELD MARA-LABOR.
* chain.                                deaktiviert zu 3.0
*     FIELD MARA-SPART.
*           MODULE MARA-SPART.
*  ENDCHAIN.

*JB/4.6B: wieder aktiviert
*Prüfung, ob Spartenwechsel erlaubt bei ungleichen Geschäftsbereichen
  CHAIN.
     FIELD MARA-SPART.
           MODULE MARA-SPART.
  ENDCHAIN.
*JB/4.6B

  CHAIN.
     FIELD MARA-PRDHA.
           MODULE MARA-PRDHA.
  ENDCHAIN.
  CHAIN.                   "ch zu 4.0
     FIELD MARA-MSTDE.
     FIELD MARA-MSTAE.
           MODULE MARA-MSTDE.
  ENDCHAIN.

* AHE: 05.02.98 - A (4.0c)
* neues Feld
  CHAIN.
     FIELD MARA-KZEFF.
*          MODULE MARA-KZEFF.  " nicht nötig !
  ENDCHAIN.
* AHE: 05.02.98 - E

* AHE: 07.05.98 - A (4.0c)
* neues Feld
  FIELD MARA-MTPOS_MARA.
* AHE: 07.05.98 - E
*
  MODULE SET_DATEN_SUB.
*

PROCESS ON VALUE-REQUEST.
* Selbstprogrammierte Eingabehilfen
     FIELD MARA-MEINS  MODULE MEKFM_HELP.
     FIELD MARA-PRDHA  MODULE MARA-PRDHA_HELP.
*    FIELD MARA-SPART  MODULE MARA-SPART_HELP.   "//zu3.0 deaktiviert
                                                 "br / ch

Einfügen Module module user_spec und via Doppelcklick einen Include dafür anlegen.
Beispiel INCLUDE : 'MARA-MSTAE' immer nur Anzeigen!

Code: Alles auswählen.

*----------------------------------------------------------------------*
***INCLUDE LZMATSTAMMO07 .
*----------------------------------------------------------------------*
*&---------------------------------------------------------------------*
*&      Module  USER_SPEC  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
module USER_SPEC output.
* ex Dynpro 2001

*break sapuser.


** Beim Hinzufügen oder Ändern
  IF t130m-aktyp = aktyph OR
     t130m-aktyp = aktypv.

      LOOP AT SCREEN.

        IF screen-name = 'MARA-MSTAE'.
*          screen-required = 1.
          screen-INPUT = 0.
          MODIFY SCREEN.
        ENDIF.
      ENDLOOP.

  ENDIF.

endmodule.                 " USER_SPEC  OUTPUT
so "einfach" ist das Ganze. :wink:

Mit dieser Technik kann man auch Felder VORBELEGEN !
z.B. Muss-Felder, die nur einen Wert zulassen. (der User wird es danken !)

gruß Jens

Folgende Benutzer bedankten sich beim Autor Tron für den Beitrag (Insgesamt 4):
ewxMurdockblack_adeptThomas R.

<:: XING-Gruppe Tricktresor::>
Die deutsche Rechtschreibung ist Freeware, du darfst sie kostenlos nutzen –
Aber sie ist nicht Open Source, d. h. du darfst sie nicht verändern oder in veränderter Form veröffentlichen.

gesponsert
Stellenangebote auf ABAPforum.com schalten
kostenfrei für Ausbildungsberufe und Werksstudenten


Re: How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von Alexander D. (Expert / 682 / 30 / 84 ) »
nicht als Kritik, sondern als Hinweis oder Ergänzung gedacht: den gleichen Effekt erreicht man mit einer Zeile im GuiXT:
noinput F[MARA-MSTAE]

der Befehl noinput gehört zu der kostenlosen Ausstattung von GuiXT und kann von jedem eingesetzt werden, vorausgesetzt man nutzt ein Windows-GUI.

Code: Alles auswählen.

Mit dieser Technik kann man auch Felder VORBELEGEN !
z.B. Muss-Felder, die nur einen Wert zulassen. (der User wird es danken !)
auch da kann GuiXT seine Stärken ausspielen. Sowohl Set als auch Default sind standard-Befehle aus der kostenlosen Version
Zuletzt geändert von Alexander D. am 09.11.2012 23:14, insgesamt 1-mal geändert.
schöne Grüße
Alexander

ECC 6.0 EHP 7

Re: How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von Unit605 (Expert / 975 / 37 / 93 ) »
Hi Tron (Jens),

waere es nicht einfacher, das Verhalten des Feldes (unsichtbar, Display, Muss-/Kann-Feld),
ueber Field Sel.Groups (155) im IMG Customizing Materialstamm (TCode OMSR) zu steuern?

Welche Vorteil/Nachteile hat Deine angebotene Vorgehensweise gebenueber dem TCode OMSR?

Ich nehme an, obwohl Du diese Dokumentation verwendest:

Code: Alles auswählen.

* ÄNDERUNG Customer Screen modification ÄNDERUNG
dass es sich nicht um eine "echte" Modification handelt.

Nachtrag: Ich will Dein Posting absolut nicht negativ kritisieren, sondern ich finde es echt cool, auch andere Moeglichkeiten aufgezeigt zu bekommen, die man evtl. woanders nutzen kann/muss.



Gruss Unit605

Re: How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von Tron (Top Expert / 1327 / 35 / 331 ) »
Moin Alexander, Unit605 und Freunde des Materialstamms.
Ihr habt natürlich Recht, für eine Feldvorbelegung (ohne Kondition) sind die GuiXt und Customizinglösung Felder zu Feldauswahlgruppen zuordnen die zu
bevorzugenden Methoden. In sofern war mein Beispiel aus dem Jahre 2010 nicht besonders gut( dafür einfach) gewählt.
Die Dynproanpassung der Logik ist, wie Unit605 bemerkte, natürlich keine Modifikation (= Änderung eines SAP Objekts) .
nicht als Kritik, sondern als Hinweis oder Ergänzung gedacht: den gleichen Effekt.....
Eine Community lebt von der "Response" seiner Mitglieder, ergo bin ich mehr erfreut, auch wenn es mal kritisch sein sollte.
Umso mehr bin ich auf die "Response" des zweiten Teil gespannt.

lg Jens
<:: XING-Gruppe Tricktresor::>
Die deutsche Rechtschreibung ist Freeware, du darfst sie kostenlos nutzen –
Aber sie ist nicht Open Source, d. h. du darfst sie nicht verändern oder in veränderter Form veröffentlichen.

Re: How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von Tron (Top Expert / 1327 / 35 / 331 ) »
Materialstamm anpassen : Teil II
Matstamm "Reloaded"

Im 2-ten Teil möchte ich den Einbau eines Zusatzfeldes näher beleuchten.
Dabei soll :

- die Grunddatentabelle MARA um ein Textfeld erweitert werden.
- Das neue Feld (e.g. ZUSATZTEXT/CHAR40) soll beschreibbar sein
- Es soll im INITIAL-Fall bei Anlegen/ Ändern mit einem Text vorbelegt werden.

Als erstes ermitteln wir das gewünschte Dynpro und die Stelle, die wir mit unserem Zusatzfeld ergänzen möchten. (e.g. FUGR MGD1 / Dynpro 1002)
Bild

nun denn:

MARA erweitern mit der Transaktion SE11
Bild

wir legen einen APPEND an und tragen den neuen Feldnamen und das Datenelement ein. Den bereits vorhanden Daten der MARA passiert so nichts.

Bild

Bei dem Datenelement haken wir Änderungsbelege an. (für MM04)
Bild

Das Aktivieren dauert etwas(keine Panik), da der Materialstamm an sehr vielen Stellen verwendet wird und viele Abhängigkeiten existieren.
Der Transport des WB-Auftrags in das Produktivsystem sollte in der Nachtzeit erfolgen, da ansonsten die Transaktion ST22 als "Highscore-Counter" fungiert. ;)
(wer es dennoch vergeigt... Einfach Hand hoch und laut rufen "Die Dumps gehen heute alle auf mich" !!.... vielleicht hilfts ;) )

Das Ergebnis dieser Aktion:
Bild

Im Customizing (SPRO) Programm für benutzereigene Subscreens anlegen
wird eine Funktionsgruppe(e.g. YMATSTAMM) mit allen Programmen und den Grund-Dynpros durch das Customizing angelegt.
Bitte ein Paket wählen (<> $TMP), damit ein Transportauftrag angelegt wird.
(Falls wir nicht die Ersten sind, die hier gewirkt haben, kann man prüfen, ob es nicht schon eine Kopie gibt, die man ggf. mitbenutzen könnte.)
Bild
Dann sieht´s so aus.
Bild

Über den Customizing Punkt Aufbau der Datenbilder pro Bildsequenz definieren
kann man sich die Inhalte der Reiter/Dynpros anzeigen lassen. (e.g. Bildsequenz 21)
Diese Info benötigen wir später zum Kopieren .
Bild

Nun kopieren wir das Dynpro (eg.1002) in unsere neue Funktionsgruppe.
Bild

Bild

Bild
ein guter Zeitpunkt mal zu aktivieren, falls noch nicht geschehen.

..Wieder im customizing Aufbau der Datenbilder pro Bildsequenz definieren
KOPIEREN wir die Bildsequenz (e.g. 21 auf Y1) Da wir natürlich nicht die Sequenzen der SAP ändern wollen !
Bild

Bild

Bild

Unsere neue Bildsequenz (e.g.Y1) die wir nun anpassen.
Bild

Damit das System die neu Bildsequenz auch benutzt, tragen wir im Customizing Bildsequenzen zu Benutzern/Materialarten/Transaktionen/Branchen zuordnen
die NEUE Bildsequenz (e.g. Y1) ein. (An dieser Stelle bitte nicht "gierig" werden und jedem User seine persönliche Sicht des Matstamms spendieren... )
Bild

Da wir schon in der SPRO sind, sollten wir das Zusatzfeld in eine FELDAUSWAHLGRUPPE (e.g. 111) aufnehmen. Das erfolgt unter: Felder zu Feldauswahlgruppen zuordnen
Bild

Bild

... kleiner Test mit Label (kann auch übersprungen werden)
Bild

Nun holen wir unser "Appendfeld" auf das Dynpro.
Bild

Fehlt also nur noch die Dynpro-Logik.
Bild

Bild

Code: Alles auswählen.

* DYNPRO 1002 
PROCESS BEFORE OUTPUT.
*                      Verarbeitung vor der Ausgabe

  MODULE init_sub.
  MODULE get_daten_sub.
  MODULE feldauswahl.
  MODULE sonderfaus.
  MODULE sonfausw_in_fgruppen.
  MODULE feldhistorie.                         "Aenderungsdienst
  MODULE bildstatus.
  MODULE zusref_vorschlagen_b.
  MODULE refdaten_vorschlagen.
  MODULE zusref_vorschlagen_a.

*== EINGEFÜGT =============
* Vorbelegung falls INITIAL
  MODULE zusatztext.
*==========================

  MODULE set_daten_sub.



PROCESS AFTER INPUT.
*                      Verarbeitung nach der Eingabe
  MODULE get_daten_sub.
  CHAIN.
*    FIELD MAKT-SPRAS.
    FIELD makt-maktx.
    MODULE makt-maktx.

*== EINGEFÜGT =============
    FIELD mara-zzusatztext.
*==========================

  ENDCHAIN.
*
  MODULE set_daten_sub.
*
... und der INCLUDE

Code: Alles auswählen.

*----------------------------------------------------------------------*
***INCLUDE LYMATSTAMMO01 .
*----------------------------------------------------------------------*
*&---------------------------------------------------------------------*
*&      Module  ZUSATZTEXT  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE zusatztext OUTPUT.

  break sapuser.


** Beim Hinzufügen oder Ändern
  IF t130m-aktyp = aktyph OR
     t130m-aktyp = aktypv.

    IF mara-zzusatztext IS INITIAL.
      mara-zzusatztext = '*** bitte ausfüllen ***'.
    ENDIF.
  ENDIF.

ENDMODULE.                 " ZUSATZTEXT  OUTPUT
zu guter Letzt, der abschliessende Test (spricht wohl für sich)
Bild

Bild

Bild

Bild

Bild

viel Erfolg
Jens
Zuletzt geändert von Tron am 17.11.2012 19:23, insgesamt 4-mal geändert.

Folgende Benutzer bedankten sich beim Autor Tron für den Beitrag (Insgesamt 6):
Thomas R.MurdockAlexander D.ewxblack_adeptUnit605

<:: XING-Gruppe Tricktresor::>
Die deutsche Rechtschreibung ist Freeware, du darfst sie kostenlos nutzen –
Aber sie ist nicht Open Source, d. h. du darfst sie nicht verändern oder in veränderter Form veröffentlichen.

Re: How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von black_adept (Top Expert / 3943 / 105 / 886 ) »
Hallo Jens,

schönes HowTo - gefällt mir.
Aber da du nach weiteren Reaktionen gefragt hast kommen hier ein paar Anmerkungen.

1.) Ich hoffe du planst schon "Materialstamm anpassen : Teil III" - denn aus meiner Erfahrung ist die Reaktion der Anwender nach kurzer Zeit folgende: "Klasse dass du da das neue Feld hast - das müssen wir jetzt erstmal bei 234.123 Materialien füllen. Aber wenn wir die MM17 aufrufen ( oder MASS ) funktioniert das nicht"
Kleiner Tipp: Wenn ihr am Materialstamm zu tun habt lasst euch die Berechtigung zur Transaktion MM17 im Produktivsystem geben. Das kann in vielerlei Hinsicht hilfreich sein.

2.) Du solltest darauf hinweisen, dass das Datenelement des neuen Feldes auf "Changes mitloggen" gestellt ist. Zumindest ist das bei mir der Default bei irgendwelchen neuen Feldern im Materialstamm wenn nicht irgend etwas sehr stark dagegen spricht.

3.) Fatal: Kundennamensraum für APPEND-Felder beginnt mit ZZ und nicht mit Z
live long and prosper
Stefan Schmöcker

email: stefan@schmoecker.de

Re: How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von Unit605 (Expert / 975 / 37 / 93 ) »
DANKE Jens, das ist mal 8)

Fuer den Materialstamm wissen wir jetzt wie es geht und wenn ich wollte haette ich schon einige "Abnehmer" fuer die Loesung.

Natuerlich ginge dies auch mit GuiXT, aber das ist mehr so ein Anhaengsel, was schnell zum Geschwuer werden kann.

Was mich natuerlich nun interessiert, gibt es das auch fuer andere Bereiche? Debitor/Kreditor/Bestellungen/Auftraege?
In den meisten Bereichen muss man ja mit den vorgegeben Exits vorlieb nehmen.

:up: :up: :up:

Re: How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von Alexander D. (Expert / 682 / 30 / 84 ) »
vielen Dank an Jens für das Tutorial, ich habe mich schon mehrmals gefragt wie das wohl mit dem Einbinden der Felder auf die konventionelle Weise funktionieren würde!
Unit605 hat geschrieben: Natuerlich ginge dies auch mit GuiXT, aber das ist mehr so ein Anhaengsel, was schnell zum Geschwuer werden kann.
ja, das würde gehen, unter Umständen sogar mit deutlich weniger Aufwand, das allerdings nur mit der kostenpflichtigen Version des Programms. Die Erklärung wie es laufen würde müsste eigentlich in einen eigenen Thread, da dies hier ja ein How-To für die Feldanpassung und Dynprosteuerung ist. Was mich wirklich interessieren würde (gern im separaten Thread) ist die Aussage mit dem Geschwühr. Habt ihr schlechte Erfahrungen mit GuiXT gemacht, spricht etwas aus deiner Sicht gegen seinen Einsatz?
schöne Grüße
Alexander

ECC 6.0 EHP 7

Re: How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von Tron (Top Expert / 1327 / 35 / 331 ) »
Moin liebe "Materialisten",

Ich habe mir erlaubt noch ein paar Anpassungen am Teil II vorzunehmen (Feldnamenänderung wg. Konformität / Aufnahme in Feldauswahlgruppe)
1.) Ich hoffe du planst schon "Materialstamm anpassen : Teil III" - denn ....
Selbstverständlich ... :wink:

gruß Jens
Zuletzt geändert von Tron am 09.12.2012 14:38, insgesamt 1-mal geändert.
<:: XING-Gruppe Tricktresor::>
Die deutsche Rechtschreibung ist Freeware, du darfst sie kostenlos nutzen –
Aber sie ist nicht Open Source, d. h. du darfst sie nicht verändern oder in veränderter Form veröffentlichen.

How-To: Materialstamm Feldanpassung Dynprosteuerung

Beitrag von Tron (Top Expert / 1327 / 35 / 331 ) »
Materialstamm anpassen : Teil III
Matstamm "Revolution"

Im 3-ten Teil möchte ich die Massenpflege eines Zusatzfeldes näher beleuchten.

Da die MM17 / MASS unser Zusatzfeld ignoriert, ergibt sich die Frage, wie man das neue Feld autom. nachträglich befüllt.
Unter den allseits beliebten BAPI - Funktionsbausteinen gibt es dazu BAPI_MATERIAL_SAVEDATA, welcher sich sehr gut eignet.

In Vorbereitung für den Aufruf des BAPIs muß unser Zusatzfeld(e.g. MARA-ZZUSATZTEXT) in die Erweiterungsstruktur BAPI_TE_MARA und BAPI_TE_MARAX aufgenommen werden.
(Für ein Zusatzfeld in der MARC wäre das analog BAPI_TE_MARC und BAPI_TE_MARCX etc.)
Bild

Bild

Eine weitere Voraussetzung für das erfolgreiche Ändern mit BAPI ist, daß das Zusatzfeld einer FELDAUSWAHLGRUPPE zugeordnet ist ! (siehe Teil II)

Hier nun das Codingmuster.

Code: Alles auswählen.

*&---------------------------------------------------------------------*
*& Report  ZTEST_MATSTAMM_ZZUSATZTEXT2                                 *
*&                                                                     *
*&---------------------------------------------------------------------*
*&                                                                     *
*&                                                                     *
*&---------------------------------------------------------------------*

REPORT  ztest_matstamm_zzusatztext2.

DATA  gv_material TYPE mara-matnr.


PARAMETERS: p_matnr TYPE mara-matnr DEFAULT 'B1139'.
PARAMETERS: p_text TYPE mara-zzusatztext LOWER CASE DEFAULT '<<Mein Text !>>'.

CALL FUNCTION 'CONVERSION_EXIT_MATN1_OUTPUT'
  EXPORTING
    input  = p_matnr
  IMPORTING
    output = gv_material.


PERFORM xtendmat USING gv_material p_text.

*&--------------------------------------------------------------------*
*&      Form  Xtendmat
*&--------------------------------------------------------------------*
*       text
*---------------------------------------------------------------------*
FORM xtendmat USING material TYPE matnr ztext TYPE mara-zzusatztext.
  DATA headdata type bapimathead.
  DATA return	type bapiret2.

  DATA returnmessages           type bapi_matreturn2 OCCURS 0.
  DATA:  e_rol_return           type bapiret2.
  DATA:  e_com_return           type bapiret2.


* EXTENSION Strukturen
  DATA: extensionin type TABLE OF bapiparex .
  DATA: ls_extensionin type bapiparex.
  DATA: extensioninx type TABLE OF bapiparexx .
  DATA: ls_extensioninx type bapiparexx.

* EXTENSION MARA
  DATA ls_bapi_te_mara TYPE bapi_te_mara.
  DATA ls_bapi_te_marax TYPE bapi_te_marax.

  CLEAR ls_bapi_te_mara.
  ls_bapi_te_mara-material = material.
  ls_bapi_te_mara-zzusatztext = ztext.

  ls_extensionin-structure = 'BAPI_TE_MARA'.
  ls_extensionin-valuepart1 = ls_bapi_te_mara.
  APPEND ls_extensionin to extensionin.


  CLEAR ls_bapi_te_marax.
  ls_bapi_te_marax-material = material.
  ls_bapi_te_marax-zzusatztext = 'X'.

  ls_extensioninx-structure = 'BAPI_TE_MARAX'.
  ls_extensioninx-valuepart1 = ls_bapi_te_marax.
  APPEND ls_extensioninx to extensioninx.

* KOPF Daten (Sichten) ************************************************
  headdata-material = material.
  headdata-basic_view ='X'.

  CALL FUNCTION 'BAPI_MATERIAL_SAVEDATA'
    EXPORTING
      headdata       = headdata
    IMPORTING
      return         = return
    TABLES
      returnmessages = returnmessages
      extensionin    = extensionin
      extensioninx   = extensioninx.

  IF return-type = 'E' OR return-type = 'A'.
    WRITE:/ 'Fehler Bapi'.
    WRITE:/ 'Type       ', return-type.
    WRITE:/ 'ID         ', return-id.
    WRITE:/ 'NUMBER     ', return-number.
    WRITE:/ return-message.
    WRITE:/ '-----------------------------------------'.

    CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'
      IMPORTING
        return = e_rol_return.
    WRITE:/ 'Rollback', e_rol_return-type.
  ELSE.
    CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
      EXPORTING
        wait   = 'X'
      IMPORTING
        return = e_com_return.

  ENDIF.


ENDFORM.                    "Xtendmat
viel Erfolg beim "Daten schaffen .. ohne Waffen" ;)
gruß Jens

Folgende Benutzer bedankten sich beim Autor Tron für den Beitrag:
Murdock

<:: XING-Gruppe Tricktresor::>
Die deutsche Rechtschreibung ist Freeware, du darfst sie kostenlos nutzen –
Aber sie ist nicht Open Source, d. h. du darfst sie nicht verändern oder in veränderter Form veröffentlichen.

Seite 1 von 1

Vergleichbare Themen

4
Antw.
3637
Views
Materialstamm Feldanpassung
von Murdock » 18.03.2014 11:41 • Verfasst in Dialogprogrammierung
1
Antw.
3466
Views
Dynprosteuerung-Folge
von hiesap » 29.01.2009 18:04 • Verfasst in Tips + Tricks & FAQs
2
Antw.
2530
Views
Dynprosteuerung Popup
von bapimueller » 09.08.2018 13:30 • Verfasst in Dialogprogrammierung
8
Antw.
6408
Views
Dynprosteuerung Tabelle T588M
von Nicole_80 » 11.01.2005 09:56 • Verfasst in Human Resources
10
Antw.
3972
Views
Materialstamm
von christof » 10.09.2015 10:39 • Verfasst in ABAP® für Anfänger

Über diesen Beitrag


Unterstütze die Community und teile den Beitrag für mehr Leser und Austausch

Aktuelle Forenbeiträge

Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 64
Interne Tabelle
vor 5 Tagen von black_adept 2 / 133
MaLo-Checker in ABAP
vor einer Woche von A6272 6 / 254

Newsletter Anmeldung

Keine Beiträge verpassen! Wöchentlich versenden wir lesenwerte Beiträge aus unserer Community.
Die letzte Ausgabe findest du hier.
Details zum Versandverfahren und zu Ihren Widerrufsmöglichkeiten findest du in unserer Datenschutzerklärung.

Aktuelle Forenbeiträge

Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 64
Interne Tabelle
vor 5 Tagen von black_adept 2 / 133
MaLo-Checker in ABAP
vor einer Woche von A6272 6 / 254

Unbeantwortete Forenbeiträge

Zwischensumme Adobe Forms
vor 3 Tagen von Lucyalison 1 / 64
Group Items auf einer Filterbar
vor einer Woche von Bright4.5 1 / 107
tRFC Transaktionen SM58
vor 4 Wochen von A6272 1 / 140