Maschinelle Lohnsteuerberechnung für 2019

Code: Alles auswählen.

interface ZTESTABLE
  public .


  methods READ_MATNR
    returning
      value(R_MATNR) type MATNR .
  type-pools ABAP .
  methods IS_NUMERIC
    importing
      !I_MATNR type MATNR
    returning
      value(R_IS_NUMERIC) type ABAP_BOOL .
endinterface.

Code: Alles auswählen.

class Z2BE_TESTED definition
  public
  create public .

public section.

  interfaces ZTESTABLE .

  aliases IS_NUMERIC
    for ZTESTABLE~IS_NUMERIC .
  aliases READ_MATNR
    for ZTESTABLE~READ_MATNR .
protected section.
private section.
ENDCLASS.



CLASS Z2BE_TESTED IMPLEMENTATION.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method Z2BE_TESTED->ZTESTABLE~IS_NUMERIC
* +-------------------------------------------------------------------------------------------------+
* | [--->] I_MATNR                        TYPE        MATNR
* | [<-()] R_IS_NUMERIC                   TYPE        ABAP_BOOL
* +--------------------------------------------------------------------------------------</SIGNATURE>
METHOD ztestable~is_numeric.

  IF i_matnr CO '1234567890 '.
    r_is_numeric = abap_true.
  ENDIF.

ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Instance Public Method Z2BE_TESTED->ZTESTABLE~READ_MATNR
* +-------------------------------------------------------------------------------------------------+
* | [<-()] R_MATNR                        TYPE        MATNR
* +--------------------------------------------------------------------------------------</SIGNATURE>
METHOD ztestable~read_matnr.

*** Hier steht eine Logik, die eine Materialnummer oder
*** irgendwas anderes ermittelt.

  SELECT SINGLE matnr FROM mara INTO r_matnr.

ENDMETHOD.
ENDCLASS.

Code: Alles auswählen.

*----------------------------------------------------------------------*
*       CLASS lth_2be_tested_ok DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lth_2be_tested_ok DEFINITION
INHERITING FROM z2be_tested.

  PUBLIC SECTION.
    METHODS:
      ztestable~read_matnr REDEFINITION.

  PRIVATE SECTION.
    CLASS-DATA:
      instance TYPE REF TO lth_2be_tested_ok.

ENDCLASS.                    "lth_2be_tested_ok DEFINITION

*----------------------------------------------------------------------*
*       CLASS lth_2be_tested_ok IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lth_2be_tested_ok IMPLEMENTATION.

  METHOD ztestable~read_matnr.
    r_matnr = '123'.
  ENDMETHOD.                    "read_matnr

ENDCLASS.                    "lth_2be_tested_ok IMPLEMENTATION

Code: Alles auswählen.

*----------------------------------------------------------------------*
*       CLASS lth_2be_tested_nok DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lth_2be_tested_nok DEFINITION
INHERITING FROM z2be_tested.

  PUBLIC SECTION.
    METHODS:
      ztestable~read_matnr REDEFINITION.

  PRIVATE SECTION.
    CLASS-DATA:
      instance TYPE REF TO lth_2be_tested_nok.

ENDCLASS.                    "lth_2be_tested_nok DEFINITION

*----------------------------------------------------------------------*
*       CLASS lth_2be_tested_nok IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lth_2be_tested_nok IMPLEMENTATION.

  METHOD ztestable~read_matnr.
    r_matnr = '12X'.
  ENDMETHOD.                    "read_matnr

ENDCLASS.                    "lth_2be_tested_nok IMPLEMENTATION

Code: Alles auswählen.

*----------------------------------------------------------------------*
*       CLASS ltc_aunit_example DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS ltc_aunit_example DEFINITION FOR TESTING
  DURATION SHORT
  RISK LEVEL HARMLESS.

  PRIVATE SECTION.
* ================

*---------------------------------------------------------------------*
*       static attributes
*---------------------------------------------------------------------*
    CLASS-DATA:
      "! class under test
      cut TYPE REF TO ztestable.

*---------------------------------------------------------------------*
*       instance attributes
*---------------------------------------------------------------------*

*---------------------------------------------------------------------*
*       class-constructor and -destructor
*---------------------------------------------------------------------*
    CLASS-METHODS:
       class_setup,
       class_teardown.

*---------------------------------------------------------------------*
*       constructor and -destructor
*---------------------------------------------------------------------*
    METHODS:
      setup,
      teardown.

*---------------------------------------------------------------------*
*       test methods
*---------------------------------------------------------------------*
    METHODS:
      verification FOR TESTING,
      falsification FOR TESTING.

ENDCLASS.       "ltc_aunit_example

*----------------------------------------------------------------------*
*       CLASS ltc_aunit_example IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS ltc_aunit_example IMPLEMENTATION.
  METHOD class_setup.

  ENDMETHOD.       " class_setup

  METHOD setup.

  ENDMETHOD.       " setup

  METHOD verification.

    DATA:
      cut TYPE REF TO lth_2be_tested_ok.

    CREATE OBJECT cut.

    cl_aunit_assert=>assert_equals(
      exp   = abap_true
      act   = cut->is_numeric( cut->read_matnr( ) )
      msg   = 'Fehler: MATNR ist nicht (rein) numerisch'
      level = cl_aunit_assert=>critical
      quit  = cl_aunit_assert=>method
    ).

  ENDMETHOD.       " verification

  METHOD falsification.

    DATA:
      cut TYPE REF TO lth_2be_tested_nok.

    CREATE OBJECT cut.

    cl_aunit_assert=>assert_equals(
      exp   = abap_false
      act   = cut->is_numeric( cut->read_matnr( ) )
      msg   = 'Fehler: MATNR ist nicht (rein) numerisch'
      level = cl_aunit_assert=>critical
      quit  = cl_aunit_assert=>method
    ).

  ENDMETHOD.                    "falsification

  METHOD teardown.

  ENDMETHOD.       " teardown

  METHOD class_teardown.

  ENDMETHOD.       " class_teardown
ENDCLASS.       "ltc_aunit_example