ZLOGON_SCREEN_INFO

Funktioniert's eventuell mit einer CASE-Anweisung?

Hi Bitfummler!
Die Includeauflösung muss
1. immer programmiert werden (ist zwar nur ein Funktionsbausteinaufruf, muss aber halt gemacht werden...)
2. wird die Includeauflösung bei manchen Textobjekten (unter anderem auch der "Allgemeine Text" in der SE61) unterbunden. Kein Ahnung, was das für Vorteile/ Hintergründe hat.
Gruß,

Also ich würd mal ne Meldung bei der SAP aufmachen und anmeckern, dass einerseits Includes/ Befehle nicht unterstützt werden, andererseits aber eine Systemöffnung zur Änderung des Textes im Prod-System notwendig ist und dass eure Revision das nicht so toll findet. Sollen die sich ruhig was einfallen lassen. Und wenn's nur eine gute Ausrede ist...

hallo alle,

falls es jemanden interessieren sollte. die sap verwies mich wieder auf den hinweis 205487. aber die dort angegebene loesung finde ich zu umstaendlich.

deswegen habe ich folgendes gemacht:

so10 anlage von 3 standardtexten:
- e00 (entwicklungssystem) ZLOGIN_SCREEN_INFO_E00
- t00 (testsystem) ZLOGIN_SCREEN_INFO_T00
- p00 (produktivsystem) ZLOGIN_SCREEN_INFO_P00

se37 anlage eines rfc-faehigen fubas mit den gleichen parametern, wie der fuba DOKU_UPDATE und aufruf desselbigen in dem rfc-fuba.

se38 neuer report: danke nochmal fuer's interesse
bitfummler

Re: ZLOGON_SCREEN_INFO

hallo abap_84,

hab's mittlerweile so gelöst:
************************************************************************
* ZSGL_UPD_ZLOGIN_SCREEN_INFO
* Update Allgemeinen Text ZLOGIN_SCREEN_INFO für Logon-Dynpro per RFC
* ----------------------------------------------------------------------
* ====> Dieses Programm existiert nur im E01. Alle SAP-Logonbilder
* werden von hier aus per RFC gepflegt. Hierfür muss der
* Funktionsbaustein Z_S_DOCU_UPDATE_RFC in alle Systeme importiert
* werden. Die gültigen Systeme werden in der Tabelle ZSZLOGIN
* gepflegt. Die Standardtexte als ZLOGIN_SCREEN_INIT_<sysid>
* in der Transaktion SO10.
* ----------------------------------------------------------------------
*
* Anfragemeldung an SAP vom 04.11.2008 923896/2008
*
* Sehr geehrte Damen und Herren,
*
* wir haben für unsere 3-Systemlandschaft den allgemeinen Text mit SE61 ZLOGON_SCREEN_INFO
* in jedem System lokal angelegt, da jedes System individuelle Texte im Anmeldebild hat und
* somit der Transport etwas kompliziert wäre. Jetzt habe ich von meiner Basis erfahren,
* dass die Revision bemängelt, dass im Produktivsystem aus diesem Grunde zur Entwicklung
* aufgemacht werden muss, wenn ein neuer Text gepflegt werden soll.
*
* Ich dachte mir jedoch, dass durch einen einfachen Include eines Standardtextes dieses
* Problem behoben sein sollte. Ich habe also mit So10 einen Standardtext angelegt.
* Beim Einbinden des Standardtextes jedoch in der SE61 bekomme ich folgenden Fehler:
*
* ---------------------------------------------------------------------
* Der Text ZLOGON_SCREEN_INFO_E10 Id ST Sprache DE kann nicht aufgelöst werden
* Meldungsnr. TD738
*
* Diagnose
* Sie wollen einen Text einbinden bzw. einbinden und auflösen.
*
* Systemaktivitäten
* Wenn Sie den Text einbinden u. auflösen wollen, erhalten Sie eine Fehlernachricht
* und Sie müssen eine Neueingabe der Parameterwerte vornehmen bzw. überprüfen warum das
* Auflösen nicht erfolgreich war.
*
* Wenn Sie lediglich ein INCLUDE-Kommando einbinden wollen, erhalten Sie eine Warnung.
* Nach dem Fortsetzen der Verarbeitung sollten Sie aber ergründen warum das Auflösen
* nicht erfolgreich durchgeführt werden konnte.
*
* Vorgehen
* Überprüfen Sie warum der angegebene Text nicht aufgelöst werden konnte. Es kommen dabei
* folgende Ursachen in Betracht:
*
* Der Text ist nicht vorhanden
* Sie haben keine Anzeigeberechtigung für den Text
* Sie wollen den gleichen Text einbinden (rekursives Einbinden)
*
* ------------------------------------------------------------------------
*
* Daraufhin habe ich versucht, durch IF-Abfragen das System zu steuern und den entsprechenden
* Text anzugeben. Wir müssten dann zwar wieder transportieren, aber die Revision wäre zufrieden.
* Das Problem ist, dass im SAP-Logondynpro diese Befehle mit ausgegeben werden.
*
* Was können wir tun, damit wir hier revisionssicher werden können?
*
* Vielen Dank für Ihre Hilfe
*
*
**************************************************************************************************
* SAP-Antwort:
* 06.11.2008 - 13:30:42 CET - Antwort von SAP
* *
* bitte beachten Sie Hinweis 205487.
* Dort dürften alle notwendigen Informationen vorliegen.
*
* Mit freundlichen Grüßen
*
* SAP Active Global Support - Netweaver Web Application Server
**************************************************************************************************
*
* Dieses Handling ist nicht zumutbar und hinterweltlerisch. Deswegen dieser Report.
*
* VORGEHENSWEISE:
*
* 1. Im E01 werden Standardtexte pro anzubindendes System gepflegt. Die Nomenklatur ist wie folgt
* vorgegeben:
* ZLOGIN_SCREEN_INFO_<sysid>
* und wird mit SO10 angelegt und gepflegt.
* 2. Anlegen RFC-Destination mit SM59. Nomenklatur
* ZLOGIN_<sysid>
* 3. Anlegen Eintrag in Tabelle ZSZLOGIN mit SM30. Hier werden die RFC-Destination und der
* Standardtext verknüpft.
* 4. Diesen Report starten mit entsprechender ZLOGIN-Destination. Er legt dann im Zielsystem den
* entsprechenden Text an.
*
* 5. SE61 im Zielsystem prüfen oder SAP-Logondynpro des Zielsystems aufrufen und kontrollieren
*
**************************************************************************************************

report zsgl_upd_zlogin_screen_info.

* externe Tabellen
* ----------------
tables: zszlogin, rfcdes.

* Selektionsauswahl
*------------------
parameters: p_dest like rfcdes-rfcdest obligatory.

* interne Tabellen
* ----------------
data: gs_textline type tline,
gt_textline type standard table of tline.

* Workbereich
* -----------
* S T E U E R L E I S T E
* -----------------------
start-of-selection.

break rrlike.

perform check.
perform read_text.
perform write_doku_rfc.


* P R O G R A M M E N D E
* -----------------------
end-of-selection.
message i000(zdok) with 'SE61 ZLOGIN_SCREEN_INFO wurde in ' p_dest
'upgedatet. Bitte prüfen!'.

*&---------------------------------------------------------------------*
*& Form check
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
form check.

select single * from zszlogin
where rfcdest = p_dest.
if sy-subrc <> 0.
message e000(zdok) with 'Falsche Destination (Kein Eintrag in Tabelle ZSZLOGIN)'.
endif.

endform. "check

*&---------------------------------------------------------------------*
*& Form read_text
*&---------------------------------------------------------------------*
* Lesen Standardtext
*----------------------------------------------------------------------*
form read_text.

clear: gs_textline, gt_textline[].
call function 'READ_TEXT'
exporting
client = sy-mandt
id = 'ST'
language = zszlogin-langu
name = zszlogin-td_name
object = 'TEXT'
archive_handle = 0
local_cat = ' '
* importing
* header = gs_thead
tables
lines = gt_textline
exceptions
id = 1
language = 2
name = 3
not_found = 4
object = 5
reference_check = 6
wrong_access_to_archive = 7
others = 8.

if sy-subrc <> 0.
message e000(zdok) with 'text nicht gefunden'.
endif.

endform. "read_text

*&---------------------------------------------------------------------*
*& Form write_doku_rfc
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
form write_doku_rfc.

call function 'Z_S_DOCU_UPDATE_RFC' destination p_dest
exporting
langu = zszlogin-langu
tables
line = gt_textline.

endform. "write_doku_rfc
-------
der fuba z_s_docu_update_rfc ist rfc-fähig und in jedem system, das upgedatet werden soll. das ist notwendig, da der fuba doku_update leider nicht rfc-fähig ist. der fuba ist so progammiert:

function z_s_docu_update_rfc.
*"----------------------------------------------------------------------
*"*"Lokale Schnittstelle:
*" IMPORTING
*" VALUE(LANGU) TYPE SPRAS
*" TABLES
*" LINE STRUCTURE TLINE
*"----------------------------------------------------------------------

data: gt_doculine type standard table of tline,
gs_thead type thead.

data: gv_dokstate type dokstate,
gv_doku_typ type doku_typ,
gv_dokvers type dokvers.


* muss für fuba mitgegeben werde, wird hier aber nicht gebraucht
clear: gt_doculine[].

clear: gv_dokstate, gv_doku_typ.

* Ermitteln Kopfdaten des alten Ziel-Dokutextes
call function 'DOCU_GET'
exporting
* EXTEND_EXCEPT = ' '
id = 'TX'
langu = langu
object = 'ZLOGIN_SCREEN_INFO'
* TYP = 'E'
* VERSION = 0
version_active_or_last = 'L'
* PRINT_PARAM_GET = 'X'
importing
dokstate = gv_dokstate
* DOKTITLE =
head = gs_thead
doktyp = gv_doku_typ
tables
line = gt_doculine
exceptions
no_docu_on_screen = 1
no_docu_self_def = 2
no_docu_temp = 3
ret_code = 4
others = 5.
if sy-subrc <> 0.
message id sy-msgid type sy-msgty number sy-msgno
with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
endif.

* Update Dokutext
gv_dokvers = gs_thead-tdversion.
call function 'DOCU_UPDATE'
exporting
* ACTCLASS = ' '
head = gs_thead
* NO_MASTERLANG = ' '
state = gv_dokstate
typ = gv_doku_typ
version = gv_dokvers
tables
line = line.

endfunction.

der report wird nur in einem quellsystem gestartet. bei uns das entwicklungssystem. dort werden mit der so10 standardtexte für die betroffenen systeme angelegt:

ZLOGIN_SCREEN_INFO_E00 DE TEXT ST SYSTEM
ZLOGIN_SCREEN_INFO_E00 EN TEXT ST SYSTEM
ZLOGIN_SCREEN_INFO_P00 DE TEXT ST SYSTEM
ZLOGIN_SCREEN_INFO_P00 EN TEXT ST SYSTEM
ZLOGIN_SCREEN_INFO_T00 DE TEXT ST SYSTEM
ZLOGIN_SCREEN_INFO_T00 EN TEXT ST SYSTEM

diese texte werden zur steuererung in der tabelle zczlogin hinterlegt:
MANDT MANDT CLNT 3 0 Mandant
RFCDEST RFCDEST CHAR 32 0 logische Destination (Wird bei Funktionsaufruf angegeben)
LANGU LANGU LANG 1 0 Sprachenschlüssel
TD_NAME TDOBNAME CHAR 70 0 Name

E00_rfc_dest E ZLOGIN_SCREEN_INFO_E00
E00_rfc_dest D ZLOGIN_SCREEN_INFO_E00
T00_rfc_dest E ZLOGIN_SCREEN_INFO_T00
T00_rfc_dest D ZLOGIN_SCREEN_INFO_T00
P00_rfc_dest E ZLOGIN_SCREEN_INFO_P00
P00_rfc_dest D ZLOGIN_SCREEN_INFO_P00

hier werden die rfc-verbindungen und die sprachenabhängigen standardtextnamen verbunden.

es funktioniert prima und rattert wie eine singernaehmaschine. riesen vorteil: transporte und systemöffnungen werden vermieden.

vielleicht hilft es ja dir auch
gruss bitfummler

Re: ZLOGON_SCREEN_INFO

ABAP_84 hat geschrieben:Hallo,
nachwie vor habe ich Probleme mit den Eigenschaften und den Parametern des Funktionsbausteins.
Eigenschaft = Remote fähiger Baustein
Import = ??
Export = ??
Tabellen = ??
Wenn ich in Import LANGU TYPE SPRAS eingebe kommt die Meldung
" Beim RFC sind keine Referenzparameter zugelassen "
Gruss

hallo,

das ist eine info und in der hilfe steht:
Beim RFC sind keine Referenzparameter zugelassen
Meldungsnr. FL381

Diagnose
Sie haben für einen remote aufrufbaren Funktionsbaustein einen Referenzparameter definiert. Bei diesen Funktionsbausteinen sind aber nur Werteparameter zulässig.


Vorgehen
Ändern Sie den Referenzparameter in einen Werteparameter.


also so definieren:
import: langu type spras + wertübergabe = x
export: nix
tabellen: line like tline

gruss bitfummler