Doppelklick funktioniert nur einmal... :(

Code: Alles auswählen.

REPORT z.

DATA gr_dock TYPE REF TO cl_gui_docking_container.
DATA gr_tree TYPE REF TO cl_list_tree_model.

PARAMETERS p_disp AS CHECKBOX USER-COMMAND x.
PARAMETERS p_nkey TYPE tv_nodekey MODIF ID x.


*----------------------------------------------------------------------*
*       CLASS lcl_appl DEFINITION
*----------------------------------------------------------------------*
CLASS lcl_appl DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS double_click FOR EVENT item_double_click OF cl_item_tree_model IMPORTING node_key.
ENDCLASS.                    "lcl_appl DEFINITION

*----------------------------------------------------------------------*
*       CLASS lcl_appl IMPLEMENTATION
*----------------------------------------------------------------------*
CLASS lcl_appl IMPLEMENTATION.
  METHOD double_click.
    p_nkey = node_key.
    MESSAGE s000(oo) WITH 'Wert gewählt:' node_key.
    cl_gui_cfw=>set_new_ok_code( 'X' ).
  ENDMETHOD.                    "double_click
ENDCLASS.                    "lcl_appl IMPLEMENTATION


INITIALIZATION.
  PERFORM init.

AT SELECTION-SCREEN OUTPUT.
  IF p_disp IS NOT INITIAL.
    LOOP AT SCREEN.
      IF screen-group1 = 'X'.
        screen-input = '0'.
        MODIFY SCREEN.
      ENDIF.
    ENDLOOP.
  ENDIF.

*&---------------------------------------------------------------------*
*&      Form  init
*&---------------------------------------------------------------------*
FORM init.

  IF gr_dock IS INITIAL.
    CREATE OBJECT gr_dock
      EXPORTING
        side      = gr_dock->dock_at_left
        extension = 250.
  ENDIF.

  IF gr_tree IS INITIAL.

    DATA lt_events   TYPE cntl_simple_events.
    DATA ls_events   LIKE LINE OF lt_events.
    DATA ls_item     TYPE treemlitem.
    DATA lt_items    TYPE STANDARD TABLE OF treemlitem.

    CREATE OBJECT gr_tree
      EXPORTING
        node_selection_mode = cl_list_tree_model=>node_sel_mode_single
        item_selection      = 'X' "braucht man für item double click
        with_headers        = ' '.

    CALL METHOD gr_tree->create_tree_control
      EXPORTING
        parent = gr_dock.

    ls_item-item_name = '1'.
    ls_item-class     = gr_tree->item_class_text.
    ls_item-alignment = gr_tree->align_auto.
    ls_item-font      = gr_tree->item_font_prop.
    ls_item-text      = 'Eins'.
    APPEND ls_item TO lt_items.


    CALL METHOD gr_tree->add_node
      EXPORTING
        node_key          = 'EINS'
        relative_node_key = space
        relationship      = gr_tree->relat_last_child
        isfolder          = space
        item_table        = lt_items.
    CLEAR lt_items.

    ls_item-item_name = '1'.
    ls_item-class     = gr_tree->item_class_text.
    ls_item-alignment = gr_tree->align_auto.
    ls_item-font      = gr_tree->item_font_prop.
    ls_item-text      = 'Zwei'.
    APPEND ls_item TO lt_items.

    CALL METHOD gr_tree->add_node
      EXPORTING
        node_key          = 'ZWEI'
        relative_node_key = space
        relationship      = gr_tree->relat_last_child
        isfolder          = space
        item_table        = lt_items.

    ls_events-eventid = gr_tree->eventid_item_double_click.
    APPEND ls_events TO lt_events.

    CALL METHOD gr_tree->set_registered_events
      EXPORTING
        events = lt_events.

    SET HANDLER lcl_appl=>double_click FOR gr_tree.

  ENDIF.

ENDFORM.                    "init