Control-Framework "Austausch" von Controls

Code: Alles auswählen.

REPORT.

*----------------------------------------------------------------------*
*       CLASS lcl_handler DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_handler DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS: handle_text_dblclick     FOR EVENT dblclick     OF cl_gui_textedit, " importing ... ist aber zur Demo egal
      handle_grid_double_click FOR EVENT double_click OF cl_gui_alv_grid IMPORTING sender.

ENDCLASS.                    "lcl_handler DEFINITION



DATA: gt_data_alv  TYPE STANDARD TABLE OF t000 WITH NON-UNIQUE DEFAULT KEY,
      gt_data_alv2 TYPE STANDARD TABLE OF t005 WITH NON-UNIQUE DEFAULT KEY,

      go_dock      TYPE REF TO cl_gui_docking_container,
      go_split     TYPE REF TO cl_gui_easy_splitter_container,
      go_text_l    TYPE REF TO cl_gui_textedit,
      go_text_r    TYPE REF TO cl_gui_textedit,
      go_grid      TYPE REF TO cl_gui_alv_grid,
      go_grid2     TYPE REF TO cl_gui_alv_grid.

PARAMETERS: rb_text  RADIOBUTTON GROUP rb1 DEFAULT 'X' USER-COMMAND space,
            rb_grid  RADIOBUTTON GROUP rb1,
            rb_grid2 RADIOBUTTON GROUP rb1,
            p_out    TYPE syucomm MODIF ID ni.

AT SELECTION-SCREEN OUTPUT.
  LOOP AT SCREEN.
    IF screen-group1 = 'NI'.
      screen-input = 0.
    ENDIF.
    MODIFY SCREEN.
  ENDLOOP.
  CASE 'X'.
    WHEN rb_text.
      go_text_r->set_visible( 'X' ).
      go_grid->set_visible(   ' ' ).
      go_grid2->set_visible(  ' ' ).

    WHEN rb_grid.
      go_text_r->set_visible( ' ' ).
      go_grid->set_visible(   'X' ).
      go_grid2->set_visible(  ' ' ).

    WHEN rb_grid2.
      go_text_r->set_visible( ' ' ).
      go_grid->set_visible(   ' ' ).
      go_grid2->set_visible(  'X' ).

  ENDCASE.

AT SELECTION-SCREEN.

  p_out = sy-ucomm.


INITIALIZATION.

*--------------------------------------------------------------------*
* Ausgabe vorbereiten
* Dock am Selscree, Splitter im Dock,
* Links Textedit,
* rechts Textedit und ALV
*--------------------------------------------------------------------*

*Docker
  CREATE OBJECT go_dock
    EXPORTING
      side                    = cl_gui_docking_container=>dock_at_bottom
      ratio                   = 80
      no_autodef_progid_dynnr = 'X'
    EXCEPTIONS
      OTHERS                  = 6.

* Splitter
  CREATE OBJECT go_split
    EXPORTING
      parent      = go_dock
      orientation = 1
    EXCEPTIONS
      OTHERS      = 3.

* Textedit links
  CREATE OBJECT go_text_l
    EXPORTING
      parent = go_split->top_left_container
    EXCEPTIONS
      OTHERS = 6.

* Textedit rechts
  CREATE OBJECT go_text_r
    EXPORTING
      parent = go_split->bottom_right_container
    EXCEPTIONS
      OTHERS = 6.

* ALV rechts
  SELECT *
    INTO TABLE gt_data_alv
    FROM t000.

*  CREATE OBJECT go_grid
  CREATE OBJECT go_grid
    EXPORTING
      i_parent = go_split->bottom_right_container
    EXCEPTIONS
      OTHERS   = 5.
  go_grid->set_table_for_first_display(  EXPORTING
                                          i_structure_name              = 'T000'
                                        CHANGING
                                          it_outtab                     = gt_data_alv
                                        EXCEPTIONS
                                          OTHERS                        = 4 ).

*  CREATE OBJECT go_grid2
  SELECT *
    INTO TABLE gt_data_alv2
    FROM t005.
  CREATE OBJECT go_grid2
    EXPORTING
      i_parent = go_split->bottom_right_container
    EXCEPTIONS
      OTHERS   = 5.
  go_grid2->set_table_for_first_display(  EXPORTING
                                          i_structure_name              = 'T005'
                                        CHANGING
                                          it_outtab                     = gt_data_alv2
                                        EXCEPTIONS
                                          OTHERS                        = 4 ).

*Eventhandler RECHTS definieren
  SET HANDLER lcl_handler=>handle_grid_double_click FOR go_grid.
  SET HANDLER lcl_handler=>handle_grid_double_click FOR go_grid2.

* grml - Textedit muss Doubleclick erst registrieren
  DATA: lt_events TYPE cntl_simple_events,
        ls_event  LIKE LINE OF lt_events.
  go_text_r->get_registered_events( IMPORTING
                                      events     = lt_events
                                    EXCEPTIONS
                                      cntl_error = 1
                                      OTHERS     = 2 ).
  ls_event-eventid = cl_gui_textedit=>event_double_click.
*  ls_event-appl_event = ' '.
  APPEND ls_event TO lt_events.
  go_text_r->set_registered_events( EXPORTING
                                      events                    = lt_events
                                    EXCEPTIONS
                                      cntl_error                = 1
                                      cntl_system_error         = 2
                                      illegal_event_combination = 3
                                      OTHERS                    = 4 ).


  SET HANDLER lcl_handler=>handle_text_dblclick     FOR go_text_r.


*----------------------------------------------------------------------*
*       CLASS lcl_handler IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_handler IMPLEMENTATION.
  METHOD handle_text_dblclick.
*PAI triggern
    cl_gui_cfw=>set_new_ok_code( EXPORTING new_code = 'Doubleclick in Textedit' ).

  ENDMETHOD.                    "handle_text_DBLCLICK

  METHOD handle_grid_double_click.
    CASE sender.
      WHEN go_grid.
        cl_gui_cfw=>set_new_ok_code( EXPORTING new_code = 'Doubleclick in Grid1' ).
      WHEN go_grid2.
        cl_gui_cfw=>set_new_ok_code( EXPORTING new_code = 'Doubleclick in Grid2' ).
    ENDCASE.
  ENDMETHOD.                    "handle_grid_DOUBLE_CLICK

ENDCLASS.                    "lcl_handler IMPLEMENTATION