Merkmalskonfiguration in SD-Aufträgen

Re:

PARAMETERS:
  p_vbeln TYPE vbeln_va DEFAULT '123456',
  p_posnr TYPE posnr DEFAULT '000010'.
select-options:
  s_atnam for ls_erg-atnam.

START-OF-SELECTION.

ewx hat geschrieben:Hi Henry,

es gibt schicke Funktionsbausteine mit denen man die Konfiguration lesen kann:
CE_I_GET_CONFIGURATION
CUXI_CONFIGURATION_GET

Ansonsten schau dir mal den folgenden Join an:


http://www.tricktresor.de/content/index ... 125&aID=68

Code: Alles auswählen.

REPORT zzconf01 .

DATA:
  l_objkey TYPE ibobjkey,
  BEGIN OF ls_erg,
    atwrt TYPE atwrt,
    atflv TYPE atflv,
    atnam TYPE atnam,
    anzdz TYPE anzdz,
    atbez TYPE atbez,
  END OF ls_erg.

PARAMETERS:
  p_vbeln TYPE vbeln_va DEFAULT '123456',
  p_posnr TYPE posnr DEFAULT '000010'.
select-options:
  s_atnam for ls_erg-atnam.

START-OF-SELECTION.

  CONCATENATE p_vbeln p_posnr INTO l_objkey.

 SELECT ibsymbol~atwrt
        ibsymbol~atflv
        cabn~atnam
        cabn~anzdz
        cabnt~atbez
   FROM ibsymbol
  INNER JOIN ibinvalues 
          ON ibinvalues~symbol_id = ibsymbol~symbol_id
  INNER JOIN ibin    ON ibin~in_recno        = ibinvalues~in_recno
  INNER JOIN ibinown ON ibinown~instance     = ibin~instance
  INNER JOIN cabn    ON cabn~atinn           = ibsymbol~atinn
  INNER JOIN cabnt   ON cabnt~atinn          = cabn~atinn
   INTO ls_erg
  WHERE ibinown~objkey = l_objkey
    AND ibinown~inttyp = '0001'     "Auftragsposition
    and cabn~atnam     in s_atnam
    AND cabnt~spras    = sy-langu.

    WRITE: / ls_erg-atbez, ls_erg-atnam.

    IF ls_erg-atflv IS INITIAL.
      WRITE ls_erg-atwrt.
    ELSE.
      WRITE  ls_erg-atflv EXPONENT 0 DECIMALS ls_erg-anzdz.
    ENDIF.


  ENDSELECT.

Gruß, Enno