Tipp für Selectionsbild?

Code: Alles auswählen.

* Selection Screen
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME.
PARAMETER: p_check AS CHECKBOX USER-COMMAND check,
           p_char10(10) TYPE c MODIF ID mid,
           p_rb1   RADIOBUTTON GROUP rb USER-COMMAND radi,
           p_char20(20) TYPE c,
           p_rb2   RADIOBUTTON GROUP rb,
           p_char30(30) TYPE c.
SELECTION-SCREEN END   OF BLOCK b1.


AT SELECTION-SCREEN OUTPUT.
  LOOP AT SCREEN.
***   p_char10
*     Um auch den Text des Paramters zu verstecken mit MODIF ID arbeiten
    IF screen-group1 = 'MID'.
*     Wenn die Checkbox angeklickt ist wird P_CHAR10 eingabebereit dargestellt
      IF p_check = 'X'.
        screen-active = 1.
*     Sonst P_CHAR10 verstecken
      ELSE.
        screen-active = 0.
      ENDIF."p_check = 'X'.
    ENDIF."screen-group1 = 'MID'.
***   p_Char20
    IF screen-name = 'P_CHAR20'.
*   Wenn der erste Radiobutton ausgewählt ist P_CHAR20 eingabebereit darstellen
      IF p_rb1 = 'X'.
        screen-input = 1.
*   Sonst P_CHAR20 auf nicht eingabebereit setzten
      ELSE.
        screen-input = 0.
      ENDIF. " p_rb1 = 'X'.
    ENDIF. "screen-name = 'P_CHAR20'
***   p_Char30
    IF screen-name = 'P_CHAR30'.
*   Wenn der zweite Radiobutton ausgewählt ist P_CHAR30 eingabebereit darstellen
      IF p_rb2 = 'X'.
        screen-input = 1.
*   Sonst P_CHAR30 auf nicht eingabebereit setzten
      ELSE.
        screen-input = 0.
      ENDIF. " p_rb2 = 'X'.
    ENDIF. "screen-name = 'P_CHAR30'

*   Änderungen übernehmen
    MODIFY SCREEN.
  ENDLOOP.

START-OF-SELECTION.
  WRITE: / 'Char 10:', p_char10,
         / 'Char 20:', p_char20,
         / 'Char 30:', p_char30.